EXCEL-Aufgaben zur Gleitzone

Gleitzone im Niedriglohnbereich - Berechnung für 2017

Erstellen Sie folgende Tabelle. Die grauen Zellen enthalten Formeln. Die gelben Zellen sind Eingabefelder.

Berechnung der SV-Beiträge in der Gleitzone für 2017

In den Zellen D3, D6, D7, D8 und D9 werden mit der Datenüberprüfung (Gültigkeitsprüfung) mögliche Zelleinträge festgelegt. In D3 sollen nur Dezimalzahlen zwischen 450,01 und 850 zulässig sein. Abbildung für Zelle D3:

Die Besonderheiten bei schwankendem Verdienst werden hier nicht behandelt. Trotz Schwankungen (mehr oder weniger Stunden im Monat oder Zahlung von Urlaubs- bzw. Weihnachtsgeld) kann der Verdienst im gesamten Jahr innerhalb der Gleitzone liegen. Entscheidend ist der Durchschnitt. Für die Berechnung der SV-Beiträge sind dann drei Fälle möglich:

Entgelt liegt innerhalb der Gleitzone
Normale Gleitzonenregelung
Entgelt liegt unterhalb der Gleitzone
In solchen Fällen errechnet sich die beitragspflichtige Einnahme durch Multiplikation des Faktors F mit dem erzielten Arbeitsentgelt.
Wird hier nicht behandelt.
Entgelt liegt oberhalb der Gleitzone
Die Beitragsberechnung erfolgt nach den allgemeinen Regelungen zur Beitragsberechnung in der Sozialversicherung.
Wird hier nicht behandelt.

Diese Aufgabe behandelt nur den ersten Fall (weitere Informationen zur Gleitzone).

In D6, D7 und D8 sind nur ja oder nein zulässig. Wählen Sie im Feld Zulassen die Option Liste aus. Geben Sie in das Feld Quelle die zwei Listenwerte mit Semikolon als Trennzeichen ein.

In D9 sollen nur Werte bis 5% zulässig sein. Wählen Sie dazu Dezimalzahlen von 0 bis 0,05 (entspricht 5%).

In D5 ist mit einer Formel die fiktive beitragspflichtige Einnahme zu berechnen. Hier gab es durch die Minijob-Reform eine große Veränderung.

Berechnung von April 2003 bis Dezember 2012	Berechnung ab Januar 2013
*F 400 + (2 - F) * (Arbeitsentgelt - 400)**	*F 450 + ([850/(850-450)] - [450/(850-450)] * F) * (Arbeitsentgelt - 450)**

Unser Rechner soll die Berechnung für die Jahre ab 2013 ermöglichen. Dazu vereinfachen wir die Formel:

F * 450 + ([850/(850-450)] - [450/(850-450)] * F) * (Arbeitsentgelt - 450)

vereinfacht:

F * 450 + ([850/400] - [450/400] * F) * (Arbeitsentgelt - 450)

vereinfacht:

F * 450 + (2,125 - 1,125 * F) * (Arbeitsentgelt - 450)

Diese Formel verwenden wir für die Zelle D5. Nehmen Sie Bezug auf D3 und D4. Die Formel in D5 sieht damit so aus:
=RUNDEN(D4*450+(2,125-1,125*D4)*(D3-450);2)

Übernehmen Sie mit einem Zellbezug den Wert aus D5 in C14, den Wert aus D3 in D14 und den Wert aus D9 in B16.

Die Formeln in C15 bis C20 nehmen Bezug auf C14 und den entsprechenden Prozentwert aus Spalte B. C15 verwendet also den Beitragssatz aus B15. Denken Sie an die Berechnungsvorschrift.

Von der fiktiven Einnahme berechnet man die Gesamtbeiträge zur Kranken-, Pflege-, Renten- und Arbeitslosenversicherung unter Anwendung des jeweils halben Beitragssatzes, rundet und verdoppelt anschließend diesen Betrag. Die Rundung erfolgt auf 2 Nachkommastellen. Das betrifft die Zellen C15, C17, C19 und C20.
Vom Beschäftigten allein zu tragende Beitragsanteile werden durch Anwendung des maßgebenden Beitragssatzes oder Beitragszuschlags auf die beitragspflichtige Einnahme berechnet und gerundet. Das betrifft die Zellen C16 und C18.

Übersicht der Sozialversicherungsbeiträge 2017

Sie brauchen also die Funktion RUNDEN.
Im ersten Schritt vernachlässigen wir die Besonderheiten für Sachsen in der Pflegeversicherung und die Möglichkeit der Nichtanwendung der Gleitzone in der Rentenversicherung.
Stellen Sie die Auswahl in den Zellen D6, D7 und D8 wie im Bildschirmbild ein (D6 nein; D7 und D8 ja). Die kopierfähige Formel in C15 sieht so aus:
=RUNDEN(B15/2*$C$14;2)*2
Kopieren Sie die Formel von C15 in C17, C19 und C20. Das Ergebnis sieht so aus:
Zelle C17: =RUNDEN(B17/2*$C$14;2)*2
Zelle C19: =RUNDEN(B19/2*$C$14;2)*2 (Besonderheit Rentenversicherung wird später eingearbeitet)
Zelle C20: =RUNDEN(B20/2*$C$14;2)*2

Jetzt werden noch die zwei vom Beschäftigten allein zu tragenden Beitragsanteile in C16 und C18 berechnet.
Dazu muss aber zuerst noch eine Berechnung in B18 vorgenommen werden. Wenn in D7 ein "ja" steht, soll in B18 eine 0 stehen, ansonsten soll in B18 0,25% erscheinen. Wir brauchen die WENN-Funktion.
=WENN(D7="ja";0;0,25%)
In B16 haben wir ja schon mit einem Zellbezug den Wert aus D9 übernommen.

Die kopierfähige Formel in C16 sieht so aus:
=RUNDEN(B16*$C$14;2)
Kopieren Sie die Formel von C16 in C18. Das Ergebnis sieht so aus:
=RUNDEN(B18*$C$14;2)

Wenn der Arbeitnehmer keine Elterneigenschaft besitzt, wird in D7 ein "nein" eingetragen und es muss folgendes passieren:

In B18 steht jetzt 0,25% und in C18 wird der Beitragszuschlag zur Pflegeversicherung für Kinderlose berechnet. Das sind in diesem Fall 1,32 € (0,25% von 529,94 €)

Die Arbeitgeberanteile in Spalte D werden als nächstes berechnet.
In D16 und D18 können wir eine 0 eintragen. Es handelt sich um die zwei vom Beschäftigten allein zu tragenden Beitragsanteile.
In den Formeln der Zellen D15, D17, D19 und D20 wird nur der Beitragssatz in Spalte B durch zwei geteilt und mit D14 multipliziert. Die Rundung erfolgt ebenfalls auf 2 Nachkommastellen. Die kopierfähige Formel in D15 sieht so aus:
=RUNDEN(B15/2*$D$14;2)
Kopieren Sie die Formel von D15 in D17, D19 und D20. Das Ergebnis sieht so aus:
Zelle D17: =RUNDEN(B17/2*$D$14;2) (Besonderheit Land Sachsen wird später eingearbeitet)
Zelle D19: =RUNDEN(B19/2*$D$14;2)
Zelle D20: =RUNDEN(B20/2*$D$14;2)

Die Arbeitnehmeranteile in Spalte E werden als nächstes berechnet.
Dazu werden von den Gesamtbeiträgen die Arbeitgeberanteile abgezogen. In E15 steht also
=C15-D15
Kopieren Sie die Formel von E15 bis E20.

Bilden Sie in Zeile 21 die Summen der Zellen aus den Zeilen 15 bis 20. In der verbundenen Zelle D22 ist zur Kontrolle die Summe der Arbeitgeberanteile und Arbeitnehmeranteile zu bilden (D21 + E21).

Besonderheit Land Sachsen

Als nächstes betrachten wir das Land Sachsen. Wenn in D6 ein "ja" steht, muss folgendes passieren:

Gleitzone in Sachsen und Elterneigenschaft vorhanden

Bei diesem Beispiel wurde die Elterneigenschaft in D7 wieder auf ja gestellt.

Der Arbeitgeberanteil ist in Sachsen niedriger. Wenn wir diesen verändern, wird der Arbeitnehmeranteil automatisch größer. Das erste Prozent zahlt in Sachsen der Arbeitnehmer allein (ausführliche Informationen zur Beitragsberechnung in Sachsen).
Hintergrund: Der Beitragssatz wurde am 01.01.1995 auf 1% der beitragspflichtigen Einnahmen festgesetzt. Zum Ausgleich der Arbeitgeberbeiträge sollten die Bundesländer einen gesetzlichen landesweiten Feiertag, der stets auf einen Werktag fällt, aufheben. In Bundesländern die den Feiertag gestrichen haben (alle außer Sachsen) wurde der Beitrag von AG und AN je zur Hälfte (je 0,5%) getragen. In Sachsen hatten die AN den Beitrag allein zu tragen (AN 1% und AG 0%). Die späteren Beitragserhöhungen wurden ohne weitere Bedingungen je zur Hälfte auf AG und AN aufgeteilt. Damit ist die Beitragsverteilung in Sachsen 2017 so:
Arbeitgeber 0,775% und Arbeitnehmer 1,775%.

Wir müssen also mit einer WENN-Funktion in D17 die Zelle D6 (Sachsen) abfragen. Die Formel in D17 sieht so aus:
=WENN(D6="ja";RUNDEN((B17-1%)/2*$D$14;2);RUNDEN(B17/2*$D$14;2))
Wenn in D6 ein ja für Sachsen steht, wird vom Beitragssatz in B17 1,0% abgezogen und der Rest durch zwei geteilt (Klammersetzung beachten!). Dieser Betrag wird mit D14 multipliziert und das Ergebnis muss gerundet werden. Der SONST-Wert der WENN-Funktion ist die Berechnung die vorher schon in der Zelle stand.

Besonderheit Rentenversicherung

Das letzte Problem ist die Möglichkeit des Arbeitnehmers, auf die Anwendung der Gleitzone in der Rentenversicherung zu verzichten. Der Arbeitnehmer muss das schriftlich gegenüber dem Arbeitgeber erklären. Die Erklärung kann nur mit Wirkung für die Zukunft und bei mehreren Beschäftigungen nur einheitlich abgegeben werden. Sie ist für die Dauer der Beschäftigungen bindend.
Hintergrund: Verminderte Rentenversicherungsbeiträge führen auch zu einer verminderten Rente.

Wir müssen die Formel in C19 anpassen. Wenn in D8 ein "nein" steht, muss folgendes passieren:

Verzicht auf die Anwendung der Gleitzone in der Rentenversicherung

Bei diesem Beispiel wurde die Elterneigenschaft in D7 wieder auf ja gestellt und Sachsen in D6 auf nein.

Wenn in D8 ein nein steht, wird der Gesamtbeitrag zur Rentenversicherung nicht von der fiktiven beitragspflichtigen Einnahme in C14 sondern vom tatsächlichen Arbeitsentgelt in D14 berechnet. Die Formel in C19 sieht so aus:
=RUNDEN(WENN(D8="ja";B19/2*$C$14;B19/2*$D$14);2)*2
Wenn in D8 ein ja steht, erfolgt die normale Berechnung (halber Beitragssatz mal fiktive beitragspflichtige Einnahme) sonst wird der halbe Beitragssatz mit dem tatsächlichen Arbeitsentgelt multipliziert. Die WENN-Funktion ist in der Funktion RUNDEN enthalten. Das Ergebnis der Funktion RUNDEN wird mit zwei multipliziert.
In unserem Fall steigt der Gesamtbeitrag zur Rentenversicherung auf 112,20 €. Der Arbeitgeberanteil beträgt immer noch 56,10 €. Der Arbeitnehmeranteil beträgt jetzt auch 56,10 €.

Die Zellen C23 bis C28 wurden zu einer Zelle verbunden. Hier soll eine Meldung (siehe Abbildung) erscheinen, wenn in D8 ein "nein" steht. Sie brauchen eine einfache WENN-Funktion (der Meldungstext muss in Anführungszeichen stehen).